/**
 * Handle meta information related to pulling articles from Dev.to
 */
module devtopull;

import std.datetime;
import std.range;

import vibe.data.json;

import devto.api;

version(unittest) {
    import unittesting.articlegenerator;
    import std.algorithm : map, until, equal, fold;
}

/**
 * Provides information about the last execution to pull.
 *
 * This structure will allow retrieving newer articles since the last session.
 */
struct PullState {
    /// When the pull was executed
    SysTime datePulled;
    /// The newest article ID obtained during the pulling
    uint lastArticle;
}

/**
 * Determine if an article is newer than the last PullState.
 */
@safe pure nothrow @nogc
auto isNewerArticle(const ArticleMe am, const PullState ps) {
    return am.id > ps.lastArticle;
} unittest {
    PullState ps;
    ps.datePulled = SysTime(DateTime(2018, 1, 1, 10, 30, 0), UTC());
    ps.lastArticle = 10_000;
    alias inPreviousPull = (x) => !x.isNewerArticle(ps);
    auto devreq = generate!fakeArticleMe
        .seqence(ps.datePulled)
        .map!(x => x.deserializeJson!(ArticleMe))
        .take(3);
    assert(devreq.until!inPreviousPull.empty);
} unittest {
    PullState ps;
    ps.datePulled = SysTime(DateTime(2018, 1, 1, 10, 30, 0), UTC());
    ps.lastArticle = 9_999;
    alias inPreviousPull = (x) => !x.isNewerArticle(ps);
    auto devreq = generate!fakeArticleMe
        .seqence(ps.datePulled)
        .map!(x => x.deserializeJson!(ArticleMe))
        .take(3)
        .map!(x => cast(immutable(ArticleMe))x);
    assert(devreq.until!inPreviousPull.map!(x => x.id).equal([10_000]));
}

/**
 * Deserializes file into the PullState structure
 */
@safe
PullState readLastPull(string filename) {
    import std.file : readText;
    return deserializeJson!(PullState)(readText(filename));
}

/**
 * Serializes PullState structure into file
 */
@trusted
void saveLastPull(const PullState ps, string filename) {
    import util.file : fileWriter;
    import std.algorithm : copy;
    serializeToPrettyJson(ps).copy(fileWriter(filename));
}

struct DevToRange {
    private const(ArticleMe)[] function(uint page) @safe articlePage;

    const(ArticleMe)[] data;
    uint page;

    @safe nothrow pure
    auto front() {
        return data.front;
    }

    @safe nothrow pure
    auto empty() {
        return data.empty;
    }

    @safe pure
    auto popFront() {
        data.popFront;
    }
}

@safe
auto devtoMyArticles() {
    DevToRange dtv;
    dtv.articlePage = &devArticles;
    dtv.data = dtv.articlePage(1);
    return dtv;
}

@safe
auto devArticles(uint page) {
    import vibe.core.log;
    import vibe.http.client;
    import std.process;
    import std.format;

    const(ArticleMe)[] ret;

    requestHTTP(format!"https://dev.to/api/articles/me/all?page=%s"(page),
        (scope req) @safe {
            req.headers.addField("api-key", environment["appkey"]);
        },
        (scope res) @safe {
            logInfo("Response: %d", res.statusCode);
            if(res.statusCode != 200)
                return;
            auto data = res.readJson();
            auto savePath = "devArticles";
            ret = meArticles(data);
        }
    );

    return ret;
}